search

Arbitrum Timelock

hashtag
Overview

This example showcases how FPS can be utilized for simulating proposals for the Arbitrum timelock on mainnet. Specifically, it upgrades the WETH gateway on L1. The proposal involves deploying a new implementation contract ARBITRUM_L1_WETH_GATEWAY_IMPLEMENTATION and a governance action contract ARBITRUM_GAC_UPGRADE_WETH_GATEWAY. Then, the timelock employs upgradeExecutor to upgrade the WETH gateway. The proposer for the L1 timelock should always be the Arbitrum bridge.

The relevant contract can be found in the mocks folderarrow-up-right.

Let's review each of the overridden functions:

  • name(): Defines the name of the proposal.

    function name() public pure override returns (string memory) {
    return "ARBITRUM_L1_TIMELOCK_MOCK";
}

  • description(): Provides a detailed description of the proposal.

    function description() public pure override returns (string memory) {
    return "Mock proposal for upgrading the WETH gateway";
}

  • deploy(): This function demonstrates the deployment of a new MockUpgrade, which will be used as the new implementation for the WETH Gateway Proxy and a new GAC contract for the upgrade.

    function deploy() public override {
    // Deploy new WETH gateway implementation if not already deployed
    if (
        !addresses.isAddressSet("ARBITRUM_L1_WETH_GATEWAY_IMPLEMENTATION")
    ) {
        // In a real case, this function would be responsible for
        // deploying a new implementation contract instead of using a mock
        address l1NFTBridgeImplementation = address(new MockUpgrade());

        addresses.addAddress(
            "ARBITRUM_L1_WETH_GATEWAY_IMPLEMENTATION",
            l1NFTBridgeImplementation,
            true
        );
    }

    // Deploy new GAC contract for gateway upgrade if not already deployed
    if (!addresses.isAddressSet("ARBITRUM_GAC_UPGRADE_WETH_GATEWAY")) {
        address gac = address(new GovernanceActionUpgradeWethGateway());
        addresses.addAddress(
            "ARBITRUM_GAC_UPGRADE_WETH_GATEWAY",
            gac,
            true
        );
    }
}

  • preBuildMock(): Post-deployment mock actions, such as setting a new outBox for Arbitrum bridge using vm.store foundry cheatcode.

    function preBuildMock() public override {
    // Deploy new mockOutBox address
    address mockOutbox = address(new MockOutbox());

    // This is a workaround to replace the mainnet outBox with the newly deployed one for testing purposes only
    vm.store(
        addresses.getAddress("ARBITRUM_BRIDGE"),
        bytes32(uint256(5)),
        bytes32(uint256(uint160(mockOutbox)))
    );
}

  • build(): Add actions to the proposal contract. In this example, ARBITRUM_L1_WETH_GATEWAY_PROXY is upgraded to the new implementation. The actions should be written in solidity code and in the order they should be executed. Any calls (except to the Addresses object) will be recorded and stored as actions to execute in the run function. The caller address is passed into buildModifier; it will call the actions in build. The caller is the Arbitrum timelock in this example. The buildModifier is a necessary modifier for the build function and will not work without it. For further reading, see the build function.

    function build() public override buildModifier(address(timelock)) {
    /// STATICCALL -- not recorded for the run stage

    // Get upgrade executor address
    IUpgradeExecutor upgradeExecutor = IUpgradeExecutor(
        addresses.getAddress("ARBITRUM_L1_UPGRADE_EXECUTOR")
    );

    /// CALLS -- mutative and recorded

    // Upgrade WETH gateway using GAC contract to the newly deployed implementation
    upgradeExecutor.execute(
        addresses.getAddress("ARBITRUM_GAC_UPGRADE_WETH_GATEWAY"),
        abi.encodeWithSelector(
            GovernanceActionUpgradeWethGateway.upgradeWethGateway.selector,
            addresses.getAddress("ARBITRUM_L1_PROXY_ADMIN"),
            addresses.getAddress("ARBITRUM_L1_WETH_GATEWAY_PROXY"),
            addresses.getAddress("ARBITRUM_L1_WETH_GATEWAY_IMPLEMENTATION")
        )
    );
}

  • run(): Sets up the environment for running the proposal, and executes all proposal actions. This sets addresses, primaryForkId, and timelock and calls super.run() to run the entire proposal. In this example, primaryForkId is set to mainnet and the fork for running the proposal is selected. Next, the addresses object is set by reading the JSON file. The timelock contract to test is set using setTimelock. This will be used to check onchain calldata and simulate the proposal. For further reading, see the run function.

    function run() public override {
    // Create and select the mainnet fork for proposal execution
    primaryForkId = vm.createFork("mainnet");
    vm.selectFork(primaryForkId);

    uint256[] memory chainIds = new uint256[](1);
    chainIds[0] = 1;
    // Set the addresses object by reading addresses from the json file
    addresses = new Addresses(
        vm.envOr("ADDRESSES_PATH", string("./addresses")), chainIds
    );

    // Set the timelock. This address is used for proposal simulation and checking on-chain proposal state
    setTimelock(addresses.getAddress("ARBITRUM_L1_TIMELOCK"));

    // Call the run function of the parent contract 'Proposal.sol'
    super.run();
}

  • simulate(): Executes the proposal actions outlined in the build() step. This function performs a call to _simulateActions from the inherited TimelockProposal contract. Internally, _simulateActions() simulates a call to Timelock scheduleBatcharrow-up-right and executeBatcharrow-up-right with the calldata generated from the actions set up in the build step.

    function simulate() public override {
    // Proposer must be the Arbitrum bridge
    address proposer = addresses.getAddress("ARBITRUM_BRIDGE");

    // Executor can be anyone
    address executor = address(1);

    // Simulate the actions in the `build` function
    _simulateActions(proposer, executor);
}

  • validate(): Validates that the implementation is upgraded correctly.

    function validate() public override {
    // Get proxy address
    IProxy proxy = IProxy(
        addresses.getAddress("ARBITRUM_L1_WETH_GATEWAY_PROXY")
    );

    // Ensure implementation is upgraded to the newly deployed implementation
    require(
        proxy.implementation() ==
            addresses.getAddress("ARBITRUM_L1_WETH_GATEWAY_IMPLEMENTATION"),
        "Proxy implementation not set"
    );
}

hashtag
Running the Proposal

All required addresses should be in the JSON file, including DEPLOYER_EOA address, which will deploy the new contracts. If these do not align, the script execution will fail.

The script will output the following:

It is crucial to note that two new addresses have been added to the Addresses.sol storage. These addresses are not included in the JSON files when proposal is run without the DO_UPDATE_ADDRESS_JSON flag set to true.

PreviousMainnet examplesNextCompound Governor Bravo

Last updated