search

Compound Governor Bravo

hashtag
Overview

This serves as a mainnet example of FPS, where FPS is utilized to propose adjustments for the Compound Governor Bravo. No deployments are included in this example. Specifically, this example sets Comet's borrow and supply kink to 0.75 * 1e18 through the Compound Configurator.

The contract outlined below is located in the mocks folderarrow-up-right.

Let's examine each of the functions that are overridden:

  • name(): Specifies the name of the proposal.

    function name() public pure override returns (string memory) {
    return "ADJUST_WETH_IR_CURVE";
}

  • description(): Offers a detailed description of the proposal.

    function description() public pure override returns (string memory) {
    return
        "Mock proposal to adjust the IR Curve for Compound v3 WETH on Mainnet";
}

  • build(): Add actions to the proposal contract. In this instance, borrow and supply kink are set through the configurator by Bravo's timelock. The actions should be written in Solidity code and in the order they are intended to be executed. Any calls (except to the Addresses object) will be recorded and stored as actions to execute in the run function. The caller address is passed into buildModifier, which will call actions in build. In this example, the caller is Governor's timelock. The buildModifier is a necessary modifier for the build function and will not function without it. For further reading, see the build function.

    function build()
    public
    override
    buildModifier(addresses.getAddress("COMPOUND_TIMELOCK_BRAVO"))
{
    /// STATICCALL -- not recorded for the run stage

    // get configurator address
    ICompoundConfigurator configurator = ICompoundConfigurator(
        addresses.getAddress("COMPOUND_CONFIGURATOR")
    );

    // get comet address
    address comet = addresses.getAddress("COMPOUND_COMET");

    /// CALLS -- mutative and recorded

    // set borrow kink to 0.75 * 1e18
    configurator.setBorrowKink(comet, kink);

    // set supply kink to 0.75 * 1e18
    configurator.setSupplyKink(comet, kink);
}

  • run(): Sets up the environment for running the proposal. This sets addresses, primaryForkId, and governor, and then calls super.run() to run the entire proposal. In this example, primaryForkId is set to mainnet, selecting the fork for running the proposal. Next, the addresses object is set by reading the JSON file. The Governor Bravo contract to test is set using setGovernor. This will be used to check onchain calldata and simulate the proposal. For further reading, see the run function.

    function run() public override {
    // Create and select the mainnet fork for proposal execution.
    primaryForkId = vm.createFork("mainnet");
    vm.selectFork(primaryForkId);

    uint256[] memory chainIds = new uint256[](1);
    chainIds[0] = 1;
    // Set the addresses object by reading addresses from the JSON file.
    setAddresses(
        new Addresses(
            vm.envOr("ADDRESSES_PATH", string("./addresses")), chainIds
        )
    );

    // Set Governor Bravo. This address is used for proposal simulation and checking the on-chain proposal state.
    setGovernor(addresses.getAddress("COMPOUND_GOVERNOR_BRAVO"));

    // Call the run function of the parent contract 'Proposal.sol'.
    super.run();
}

  • validate(): Validates that the supply and borrow kink are set correctly.

    function validate() public view override {
    // get configurator address
    ICompoundConfigurator configurator = ICompoundConfigurator(
        addresses.getAddress("COMPOUND_CONFIGURATOR")
    );

    // get comet address
    address comet = addresses.getAddress("COMPOUND_COMET");

    // get comet configuration
    ICompoundConfigurator.Configuration memory config = configurator
        .getConfiguration(comet);

    // ensure supply kink is set to 0.75 * 1e18
    assertEq(config.supplyKink, kink);

    // ensure borrow kink is set to 0.75 * 1e18
    assertEq(config.borrowKink, kink);
}

hashtag
Running the Proposal

All required addresses should be in the JSON file, including the DEPLOYER_EOA address, which will deploy the new contracts. If these do not align, the script execution will fail.

The script will output the following:

PreviousArbitrum TimelockNextOptimism Multisig

Last updated